Here’s that script:
; Press Ctrl+Enter to launch first URL found in current item or (if none there) in its note.
/*
Cursor may be anywhere in item or note.
The URL will launch in a new tab, unless it's an internal Dynalist link.
If it's a working internal Dynalist link, it will launch in the same window with minimal delay.
If it's a broken internal Dynalist link, it will reload Dynalist (slowly) at the current page.
If cursor is absent or on completely blank item, it will launch the first URL in the visible outline.
If URLs exist not in current item and note but in one or more visible sub-items or their notes,
then the first of these URLs will be launched.
***NOTE: This script depends on two customized Dynalist hotkeys. So, before using,
scroll down and follow instructions of 3 comments saying ***REPLACE...
; ...remembering AutoHotKey syntax:
; ^ = Ctrl, ! = Alt, + = Shift, so e.g. Ctrl+Alt+Shift+' = ^!+' and Alt+Space = !Space
*/
^Enter::
oldclip := clipboard ; Store current clipboard
clipboard = ; Empty clipboard (so ClipWait can detect when text has arrived)
Send, ^a^a ; Select entire item and note
Sleep, 100
Send, ^c ; Copy
Sleep, 100
Send, {Right} ; Deselect and return cursor to end of item
If (RegExMatch(clipboard, "s)^(.*?)(https?://)([^\s\)]+)(.*)$") > 0) { ; If URL is found (1st try)
firstURL := RegExReplace(clipboard, "s)^(.*?)(https?://)([^\s\)]+)(.*)$", "$2$3")
clipboard := firstURL
If (InStr(clipboard, "//dynalist.io") = 0) { ; If clipboard is not an internal Dynalist link...
Send, ^t ; ...then open new tab...
} Else {
Send, ^l ; ...otherwise use current tab.
} ; End of internal-Dynalist-link If/Else
Sleep, 100
; Sleep, 100
Send, ^v ; Paste URL
Sleep, 100
Send, {Enter}
} Else { ; Maybe cursor was on top (zoomed) item so that Ctrl+A, Ctrl+A didn't include note
Send, !' ; Go to note (***REPLACE with your Dynalist hotkey for "Move between item & note")
Sleep, 100
Send, {Space} ; Append space to note (ensuring that something is selected; space will be trimmed)
Sleep, 100
Send, ^a ; Select note
Sleep, 100
Send, ^c ; Copy
Sleep, 100
Send, !] ; Go to end of note (***REPLACE with your Dynalist for "Go to end of text")
Sleep, 100
Send, {Backspace} ; Delete trailing space
Sleep, 100
Send, !' ; Return to item (***REPLACE with your Dynalist hotkey for "Move between item & note")
If (RegExMatch(clipboard, "s)^(.*?)(https?://)([^\s\)]+)(.*)$") > 0) { ; If URL is found (2nd try)
firstURL := RegExReplace(clipboard, "s)^(.*?)(https?://)([^\s\)]+)(.*)$", "$2$3")
clipboard := firstURL
If (InStr(clipboard, "//dynalist.io") = 0) { ; If clipboard is not an internal Dynalist link...
Send, ^t ; ...then open new tab...
} Else {
Send, ^l ; ...otherwise use current tab.
} ; End of internal-Dynalist-link If/Else
Sleep, 100
Send, ^v ; Paste URL
Sleep, 100
Send, {Enter}
} ; End of If URL is found (2nd try)
} ; End of Else (URL wasn't found on 1st try)
clipboard := oldclip ; Restore previous clipboard
return